(玩电子) 电子技术学习与研讨
当时方位:单片机教程网 >> 根底教程 >> 阅览文章

24课:动态扫描显现接口电路及程序

作者:佚名   来历:本站原创   点击数:x  更新时刻:2007年08月14日   【字体:

    在单片机体系中动态扫描显现接口是单片机中运用最为广泛的一种显现办法之一。其接口电路是把一切显现器的8个笔划段a-h同名端连在一起,而每一个显现器的公共极COM是各自独登时受I/O线操控。CPU向字段输出口送出字形码时,一切显现器接收到相同的字形码,但究竟是那个显现器亮,则取决于COM端,而这一端是由I/O操控的,所以咱们就能自行决定何时显现哪一位了。而所谓动态扫描便是指咱们选用分时的办法,轮番操控各个显现器的COM端,使各个显现器轮番点亮。在http://www.kp0519.com还有许多关于单片机显现接口的文章,咱们能够参阅一下

   在轮番点亮扫描过程中,每位显现器的点亮时刻是极为时刻短的(约1ms),但由于人的视觉暂留现象及发光二极管的余辉效应,虽然实践上各位显现器并非一起点亮,但只需扫描的速度足够快,给人的形象便是一组安稳的显现数据,不会有闪耀感。

   下图所示便是咱们的单片机试验板上的动态扫描接口。由89c51的P0口能灌入较大的电流,所以咱们选用共阳的数码管,而且不必限流电阻,而仅仅用两只1N4004进行降压后给数码管供电,这儿仅用了两只,实践上还能扩大。它们的公共端则由PNP型三极管8550操控,明显,假如8550导通,则对应的数码管就能亮,而假如8550截止,则对应的数码管就不或许亮,8550是由P2.7,P2.6操控的。这样咱们就能经过操控P27、P26到达操控某个数码管亮或灭的意图。

下面的这个单片机程序,便是用试验板上的数码管显现0和1。

FIRST EQU P2.7 ;第一位数码管的位操控

SECOND EQU P2.6 ;第二位数码管的位操控

DISPBUFF EQU 5AH ;显现缓冲区为5AH和5BH

ORG 0000H

AJMP START

ORG 30H

START:

MOV SP,#5FH ;设置仓库

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化,所显现器,LED灭

MOV DISPBUFF,#0 ;第一位显现0

MOV DISPBUFF+1,#1 ;第二握显现1

LOOP:

LCALL DISP ;调用显现程序

AJMP LOOP

;主程序到此结束

DISP:

PUSH ACC ;ACC入栈

PUSH PSW ;PSW入栈

MOV A,DISPBUFF ;取第一个待显现数

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形码

MOV P0,A ;将字形码送P0位(段口)

CLR FIRST ;开第一位显现器位口

LCALL DELAY ;延时1毫秒

SETB FIRST ;封闭第一位显现器(开端预备第二位的数据)

MOV A,DISPBUFF+1 ;取显现缓冲区的第二位

MOV DPTR,#DISPTAB

MOVC A,@A+DPTR

MOV P0,A ;将第二个字形码送P0口

CLR SECOND ;开第二位显现器

LCALL DELAY ;延时

SETB SECOND ;关第二位显现

POP PSW

POP ACC

RET

DELAY: ;延时1毫秒

PUSH PSW

SETB RS0

MOV R7,#50

D1: MOV R6,#10

D2: DJNZ R6,$

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

从上面的单片机例程中能看出,动态扫描显现必须由CPU继续地调用显现程序,才干确保继续继续的显现。

   上面的这个程序能完结数字的显现,但不太有用,为什么呢?这儿仅是显现两个数字,并没有做其他的作业,因而,两个数码管轮番显现1毫秒,没有问题,实践的作业中,当然不或许只显现两个数字,仍是要做其他的作业的,这样在二次调用显现程序之间的时刻距离就不一不定了,假如时刻距离比较长,就会使显现不接连。而实践作业中是很难确保一切作业都能在很短时刻内完结的。何况这个显现程序也有点“糟蹋”,每个数码管显现都要占用1个毫秒的时刻,这在许多合是不允许的,怎么办呢?咱们能借助于守时器,守时时刻一到,发生中止,点亮一个数码管,然后立刻回来,这个数码管就会一向亮到下一次守时时刻到,而不必调用延时程序了,这段时刻能留给主程序干其他的事。到下一次守时时刻到则显现下一个数码管,这样就很少糟蹋了。

Counter EQU 59H ;计数器,显现程序经过它得知现正显现哪个数码管

FIRST EQU P2.7 ;第一位数码管的位操控

SECOND EQU P2.6 ;第二位数码管的位操控

DISPBUFF EQU 5AH ;显现缓冲区为5AH和5BH

ORG 0000H

AJMP START

ORG 000BH ;守时器T0的进口

AJMP DISP ;显现程序

ORG 30H

START:

MOV SP,#5FH ;设置仓库

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化,所显现器,LED灭

MOV TMOD,#00000001B ;守时器T0作业于形式1(16位守时/计数形式)

MOV TH0,#HIGH(65536-2000)

MOV TL0,#LOW(65536-2000)

SETB TR0

SETB EA

SETB ET0

MOV Counter,#0 ;计数器初始化

MOV DISPBUFF,#0 ;第一位一直显现0

MOV A,#0

LOOP:

MOV DISPBUFF+1,A ;第二位轮番显现0-9

INC A

LCALL DELAY

CJNE A,#10,LOOP

MOV A,#0

AJMP LOOP ;在此中心能按排恣意程序,这儿仅作演示。

;主程序到此结束

DISP: ;守时器T0的中止呼应程序

PUSH ACC ;ACC入栈

PUSH PSW ;PSW入栈

MOV TH0,#HIGH(65536-2000) ;守时时刻为2000个周期,约2170微秒(11.0592M)

MOV TL0,#LOW(65536-2000)

SETB FIRST

SETB SECOND ;关显现

MOV A,#DISPBUFF ;显现缓冲区首地址

ADD A,Counter

MOV R0,A

MOV A,@R0 ;依据计数器的值取对应的显现缓冲区的值

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形码

MOV P0,A ;将字形码送P0位(段口)

MOV A,Counter ;取计数器的值

JZ DISPFIRST ;假如是0则显现第一位

CLR SECOND ;否则显现第二位

AJMP DISPNEXT

DISPFIRST:

CLR FIRST ;显现第一位

DISPNEXT:

INC Counter ;计数器加1

MOV A,Counter

DEC A ;假如计数器计到2,则让它回0

DEC A

JZ RSTCOUNT

AJMP DISPEXIT

RSTCOUNT:

MOV Counter,#0 ;计数器的值只能是0或1

DISPEXIT:

POP PSW

POP ACC

RETI

DELAY: ;延时130毫秒

PUSH PSW

SETB RS0

MOV R7,#255

D1: MOV R6,#255

D2: NOP

NOP

NOP

NOP

DJNZ R6,D2

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

    从上面的单片机程序能看出,动态显现和静态显现比较,程序稍有点杂乱,不过,这是值得的。这个程序有必定的通用性,只需改动端口的值及计数器的值就能显现更多位数了。下面给出显现程序的流程图。<动态扫描程序框图>

 

 

 

 

 

 

 

宣布谈论】【告知老友】【保藏此文】【封闭窗口

文章谈论